ARDUİNO

Merhaba arkadaşlar. Bugün sizlerle Arduino ile RC522 RFID modülünü kullanacağız.

Gereken malzemeler:

• Arduino UNO
• Breadboard
• RC522 RFID modül ve 2 adet RFID kart/tag
• Erkek-erkek jumper kablo
• LED
• 220 Ω direnç

RFID genel anlamıyla nesnelerin radyo dalgaları kullanılarak tanınması için kullanılan teknolojidir. Günlük hayatımızda toplu taşıma biletlerinde, işyeri ve okul girişlerindeki turnikelerde karşımıza sıklıkla çıkmaktadır. Kablosuz haberleşme teknolojileri ile ilgili daha fazla bilgi edinmek isterseniz, Kablosuz Haberleşme Teknolojileri yazımızı okuyabilirsiniz.

Kullandığımız kartların kendilerine ait UID isimli bir numarası vardır. Bu numara, her kart için farklıdır. Okuyucumuza kartımızı veya anahtarlığımızı yaklaştırdığımızda bu numara okunarak işlem yapılır. Bu uygulamada, öncelikle elimizdeki kartların UID’lerini Arduino’muzun dahili EEPROM’una kaydederek ve daha sonra okuttuğumuz kartın UID’sini, bellekteki UID değerleriyle karşılaştırarak işlem yapacağız. Devre şemamız şu şekilde:

Bu adresten kartımızı çalıştırmamızda gerekli olan kütüphaneyi indirerek Arduino programının kurulu olduğu klasör altındaki librariesklasörüne MFRC522 ismiyle kaydediyoruz.

Öncelikle, elimizdeki kartları Arduino’nun EEPROM’una kaydedecek kodu yüklüyoruz:

#include <SPI.h>
#include <MFRC522.h>
#include <EEPROM.h>

#define RST_PIN 9
#define SS_PIN 10

byte readCard[4];
int successRead;

MFRC522 mfrc522(SS_PIN, RST_PIN);

MFRC522::MIFARE_Key key;

void setup()
{
  Serial.begin(9600);
  SPI.begin();
  mfrc522.PCD_Init();
  Serial.println("RFID KART KAYIT UYGULAMASI");
  Serial.println("--------------------------");
  Serial.println("Lutfen 1 numarali karti okutun");
  Serial.println();
  do {
    //okuma başarılı olana kadar getID fonksiyonunu çağır
    successRead = getID(); 
  }
  while (!successRead);
  for ( int i = 0; i < mfrc522.uid.size; i++ )
  {
    //kartın UID'sini EEPROM'a kaydet
    EEPROM.write(i, readCard[i] ); 
  }
  Serial.println("Kart EEPROM'a kaydedildi.");
  Serial.println();
  Serial.println("Lutfen 2 numarali karti okutun.");
  Serial.println();
  do {
    successRead = getID();
  }
  while (!successRead);
  for ( int i = 0; i < mfrc522.uid.size; i++ )
  {
    EEPROM.write(i + 4, readCard[i] );
  }
  Serial.println("Kart EEPROM'a kaydedildi.");
  Serial.println();
  Serial.println("Kart kayit islemi basarili!");
}

void loop()
{
}

int getID() {
  //yeni bir kart okunmadıysa 0 döndür
  if ( ! mfrc522.PICC_IsNewCardPresent()) { 
    return 0;
  }
  if ( ! mfrc522.PICC_ReadCardSerial()) {
    return 0;
  }
  Serial.print("Kart UID'si: ");
  //kartın UID'sini byte byte oku ve seri monitöre yaz
  for (int i = 0; i < mfrc522.uid.size; i++) {  //
    readCard[i] = mfrc522.uid.uidByte[i];
    Serial.print(readCard[i], HEX);
  }
  Serial.println("");
  //kart okumayı durdur ve 1 döndür (okuma başarılı)
  mfrc522.PICC_HaltA();
  return 1;
}

Bu kodu yükledikten sonra, Arduino programından “Seri Port Ekranı”nı açarak kart okuma işlemini yapıyoruz.

Burada dikkat etmemiz gereken nokta, 1 ve 2 numaralı kartların birbirinden farklı olması. Eğer okuma işlemi sırasında 1 ve 2 numaralı kart olarak aynı kartı seçersek, bir sonraki adımda kullanacağımız kod çalışmayacaktır. Kart okuma işlemi yapıldıktan sonra, aşağıdaki kodu Arduino’muza yükleyerek bir sonraki adıma geçiyoruz:

#include <SPI.h>
#include <MFRC522.h>
#include <EEPROM.h>

#define RST_PIN 9
#define SS_PIN 10
#define ledPin 7

MFRC522 mfrc522(SS_PIN, RST_PIN);

String lastRfid = "";
String kart1 = "";
String kart2 = "";

MFRC522::MIFARE_Key key;

void setup()
{
  Serial.begin(9600);
  SPI.begin();
  mfrc522.PCD_Init();
  pinMode(ledPin, OUTPUT);
  Serial.println("RFID KART OKUMA UYGULAMASI");
  Serial.println("--------------------------");
  Serial.println();
  //EEPROM'dan kart bilgisini oku
  readEEPROM();
}

void loop()
{
  //yeni kart okununmadıkça devam etme
  if ( ! mfrc522.PICC_IsNewCardPresent())
  {
    return;
  }
  if ( ! mfrc522.PICC_ReadCardSerial())
  {
    return;
  }
  //kartın UID'sini oku, rfid isimli string'e kaydet
  String rfid = "";
  for (byte i = 0; i < mfrc522.uid.size; i++)
  {
    rfid += mfrc522.uid.uidByte[i] < 0x10 ? " 0" : " ";
    rfid += String(mfrc522.uid.uidByte[i], HEX);
  }
  //string'in boyutunu ayarla ve tamamını büyük harfe çevir
  rfid.trim();
  rfid.toUpperCase();
  
  if (rfid == lastRfid)
    return;
  lastRfid = rfid;

  Serial.print("Kart 1: ");
  Serial.println(kart1);
  Serial.print("Kart 2: ");
  Serial.println(kart2);
  Serial.print("Okunan: ");
  Serial.println(rfid);
  Serial.println();
  //1 nolu kart okunduysa LED'i yak, 2 nolu kart okunduysa LED'i söndür
  if (rfid == kart1)
  {
    digitalWrite(ledPin, HIGH);
    Serial.println("LED yandi.");
  }
  if (rfid == kart2)
  {
    digitalWrite(ledPin, LOW);
    Serial.println("LED sondu.");
  }
  Serial.println();
  delay(200);

}

void readEEPROM()
{
  //EEPROM'dan ilk kartın UID'sini oku (ilk 4 byte)
  for (int i = 0 ; i < 4 ; i++)
  {
    kart1 += EEPROM.read(i) < 0x10 ? " 0" : " ";
    kart1 += String(EEPROM.read(i), HEX);
  }
  //EEPROM'dan ikinci kartın UID'sini oku
  for (int i = 4 ; i < 8 ; i++)
  {
    kart2 += EEPROM.read(i) < 0x10 ? " 0" : " ";
    kart2 += String(EEPROM.read(i), HEX);
  }
  //Okunan stringleri düzenle
  kart1.trim();
  kart1.toUpperCase();
  kart2.trim();
  kart2.toUpperCase();
}

Bu kod sayesinde, 1 numaralı kartımızı okuttuğumuzda Arduino, RC522 modülün okuduğu UID değerini EEPROM’da kayıtlı olan 1 numaralı kart değeriyle karşılaştırıyor, eğer iki değer birbirinin aynısı ise 7 numaralı pine bağladığımız LED’i yakıyor. Arduino’muz, yeni bir kart okumak üzere hazır bekler haldeyken 2 numaralı kartı okutur isek, bu sefer yanmakta olan LED söndürülüyor. Eğer EEPROM’da UID’si kayıtlı olmayan bir kart okutursak LED’in durumunda herhangi bir değişiklik olmuyor.

Sizler de elinizdeki farklı RFID kartlarla deneme yaparak farklı kartları kaydedebilirsiniz. RC522 modül, bu uygulamada karta yazma işlemi yapmadığından, uygulamayı elinizdeki desteklenen tüm kartlarla sorunsuzca kullanabilirsiniz
ARDUİNO MEGA 2560.

Arduino Mega 2560 ATmega2560 mikrodenetleyici içeren bir Arduino kartıdır. Arduino Uno 'dan sonra en çok tercih edilen Arduino kartı olduğu söylenebilir. Arduino 'nun kardeş markası olan Genuino markasını taşıyan Genuino Mega 2560 kartı ile tamamen aynı özelliklere sahiptir.    Arduino Mega 2560 'ta 54 tane dijital giriş / çıkış pini vardır. Bunlardan 15 tanesi PWM çıkışı olarak kullanılabilir. Ayrıca 16 adet analog girişi, 4 UART (donanım seri port), bir adet 16 MHz kristal osilatörü, USB bağlantısı, power jakı (2.1mm), ICSP başlığı ve reset butonu bulunmaktadır. Arduino Mega 2560 bir mikrodenetleyiciyi desteklemek için gerekli bileşenlerin hepsini içerir. Arduino Mega 2560 bir bilgisayara bağlanarak, bir adaptör ile ya da pil ile çalıştırılabilir. Arduino Mega, Arduino Duemilanove ya da Diecimila için tasarlanan shield lerin çoğu ile kullanılabilir. Arduino Mega 2560 R2 (revision 2) 8U2 HWB çizgisini toprağa çeken bir dirence sahiptir. Böylece DFU mode kullanmak kolaylaşır. Arduino Mega R3 (revision 3) ise şu ek özelliklere sahiptir;  1.0 pinout : AREF pininin yanına SDA ve SCL pinleri eklenmiştir. Reset pininin yanına iki yeni pin eklenmiştir. IOREF shield lerin karttan sağlanan voltaja adapte olmasını sağlar. İleride shield ler hem 5 V ile çalışan AVR kullanan kartlar ile hem de 3.3 V ile çalışan Arduino Due ile uyumlu olacaktır. İkinci pin ise herhangi bir yere bağlı değildir. İleride yapılacak geliştirmeler için eklenmiştir.  Daha güçlü reset devresi  Arduino Mega 2560 R1 ve R2 de kullanılan ATmega8U2 yerine R3 te ATmega16U2 kullanılmıştır. Aşağıdaki resimde Arduino Mega 2560 pinleri gösterilmektedir. Arduino Mega 2560 Teknik Özellikleri  Mikrodenetleyici : ATmega2560  Çalışma gerilimi : +5 V DC   Tavsiye edilen besleme gerilimi : 7 - 12 V DC  Besleme gerilimi limitleri : 6 - 20 V  Dijital giriş / çıkış pinleri : 54 tane (15 tanesi PWM çıkışını destekler)  Analog giriş pinleri : 16 tane  Giriş / çıkış pini başına düşen DC akım : 40 mA  3,3 V pini için akım : 50 mA  Flash hafıza : 256 KB (8 KB bootloader için kullanılır)  SRAM : 8 KB  EEPROM : 4 KB  Saat frekansı : 16 MHz  Arduino Mega 2560 kart şematiği  ATmega2560 datasheet Güç Arduino Mega 2560 bir USB kablosu ile bilgisayar bağlanarak çalıştırılabilir ya da harici bir güç kaynağından beslenebilir. Harici güç kaynağı bir AC-DC adaptör ya da bir pil / batarya olabilir. Adaptörün 2.1 mm jaklı ucunun merkezi pozitif olmalıdır ve Arduino Mega 2560 'ın power girişine takılmalıdır. Pil veya bataryanın uçları ise power konnektörünün GND ve Vin pinlerine bağlanmalıdır. Arduino Mega 2560 6 V - 20 V aralığında bir harici güç kaynağı ile beslenebilir. Ancak 7 V altında bir besleme yapıldığında 5V pini 5 V tan daha düşük çıkış verebilir ve kart kararsız çalışabilir. 12 V üzerinde bir voltaj beslemesi yapılması durumunda ise regülatör fazla ısınabilir ve karta zarar verebilir. Bu nedenle tavsiye edilen besleme gerilimi 7 V - 12 V aralığındadır.   VIN : Arduino Mega 2560 kartına harici bir güç kaynağı bağlandığında kullanılan voltaj girişidir.  5V : Bu pin Arduino kartındaki regülatörden 5 V çıkış sağlar. Kart DC power jakından (2 numaralı kısım) 7-12 V adaptör ile, USB jakından (1 numaralı kısım) 5 V ile ya da VIN pininden 7-12 V ile beslenebilir. 5V ve 3.3Vpininden voltaj beslemesi regülatörü bertaraf eder ve karta zarar verir.   3.3V : Arduino kart üzerindeki regülatörden sağlanan 3,3V çıkışıdır. Maksimum 50 mA dir.  GND : Toprak pinidir.  IOREF : Arduino kartlar üzerindeki bu pin, mikrodenetleyicinin çalıştığı voltaj referansını sağlar. Uygun yapılandırılmış bir shield IOREF pin voltajını okuyabilir ve uygun güç kaynaklarını seçebilir ya da 3.3 V ve 5 V ile çalışmak için çıkışlarında gerilim dönüştürücülerini etkinleştirebilir.  Giriş ve Çıkışlar Arduino Mega 2560 'ta bulunan 54 tane dijital giriş / çıkış pininin tamamı, pinMode(), digitalWrite() ve digitalRead() fonksiyonları ile giriş ya da çıkış olarak kullanılabilir. Bu pinler 5 V ile çalışır. Her pin maksimum 40 mA çekebilir ya da sağlayabilir ve 20-50 KOhm dahili pull - up dirençleri vardır. Ayrıca bazı pinlerin özel fonksiyonları vardır:   Serial: 0 (RX) ve 1 (TX); Serial 1: 19 (RX) ve 18 (TX); Serial 2: 17 (RX) ve 16 (TX); Serial 3: 15 (RX) ve 14 (TX) : Bu pinler TTL seri data almak (receive - RX) ve yaymak (transmit - TX) içindir. 0 ve 1 pinleri ayrıca ATmega16U2 USB-to-TTL Si çipinin ilgili pinlerine bağlıdır.   Harici kesmeler 2 (kesme 0), 3 (kesme 1), 18 (kesme 5), 19 (kesme 4), 20 (kesme 3) ve 21 (kesme 2) : Bu pinler bir kesmeyi tetiklemek için kullanılabilir.  PWM: 2 - 13 , 44 - 46 : Bu pinler analogWrite () fonksiyonu ile 8-bit PWM sinyali sağlar.  SPI: 50 (MISO), 51 (MOSI), 52 (SCK), 53 (SS) : Bu pinler SPI kütüphanesi ile SPI haberleşmeyi sağlar.  LED 13 : Digital pin 13 e bağlı bir leddir. Pinin değeri High olduğunda yanar, Low olduğunda söner.  TWI : 20 SDA 21 SCL : Wire kütüphanesini kullanarak TWI haberleşmesini destekler. (Bu pinlerin yeri Arduino Duemilanove ve Diecimila kartlardaki ile aynı değildir.)  Arduino Mega 2560 'ın 16 tane analog girişinden her biri 10 bit çözünürlüğü destekler. Varsayılan ayarlarda topraktan 5 V a kadar ölçerler. Ancak, AREF pini ve analogReference() fonksiyonu kullanılarak üst limit ayarlanabilir.   AREF : Analog girişler için referans voltajıdır. analogReference() fonksiyonu ile kullanılır.  RESET : Mikrodenetleyiciyi resetlemek içindir. Genellikle shield üzerine reset butonu eklemek için kullanılır.  Haberleşme Arduino Mega 2560 bir bilgisayar ile, başka bir Arduino ile ya da diğer mikrodenetleyiciler ile haberleşme için çeşitli imkanlar sunar. ATmega2560 mikrodenetleyicisi TTL (5V) seri haberleşme için 4 donanımsal UART'a sahiptir. Kart üzerindeki bir ATmega16U2 seri haberleşmeyi USB üzerinden kanalize eder ve bilgisayardaki yazılıma sanal bir com portu olarak görünür. 16U2 standart USB com sürücülerini kullanır ve harici sürücü gerektirmez. Ancak, Windows 'ta bir .inf dosyası gereklidir. Kart üzerindeki RX ve TX ledleri USB den seri çipe ve USB den bilgisayara veri giderken yanıp söner.  SoftwareSerial kütüphanesi Arduino Mega 2560 'ın dijital pinlerinden herhangi biri üzerinden seri haberleşmeye imkan sağlar. Ayrıca ATmega2560 TWI ve SPI haberleşmelerini de destekler.  Programlama Arduino Mega 2560 'ı programlamak için Arduino programını buradan indirmeniz gerekir. Programı indirip açtıktan sonra Tools > Board menüsünden Arduino Mega 2560 'ı seçiniz.  Arduino Mega 2560 üzerindeki ATmega2560 mikrodenetleyicisine önceden bir bootloader yüklenmiştir. Bu bootloader sayesinde Arduino 'yu programlamanız için harici bir programlayıcı donanımına ihtiyacınız olmaz. Orjinal STK500 programını kullanarak haberleşir.  Ayrıca Arduino ISP kullanarak Arduino 'nun bootloader 'ını devre dışı bırakabilir ve mikrodenetleyiciyi ICSP (In Circuit Serial Programming) pini üzerinden programlayabilirsiniz.  USB Aşırı Akım Koruması Arduino Mega 2560, bilgisayarınızın USB portunu aşırı akım ve kısa devreden koruyan resetlenebilir bir çoklu sigortası bulunur. Çoğu bilgilsayarın portlar için kendi korumaları olmasına rağmen bu sigorta ekstra bir koruma katmanı sağlar. Eğer USB portuna 500 mA den fazla bir yük binerse, sigorta otomatik olarak bağlantıyı kısa devre veya aşırı akım durumu ortadan kalkana dek keser.  BU bilgi Robotiksistem.com tarafından alınmıştır.